History : Object

History.clear.end;     // if needed, clear History first

History.start;         // starts recording, opens log file

​

// execute these lines one by one, as a little performance history

1 + 2;

p = ProxySpace.push(s.boot);

~a = {Dust.ar([1,1] * 30 ) * 0.3 };

~a.play;

~a.end(3);

​

History.started; // is it on now?

​

// stops recording history and ends logging.

History.end;

History.started;

​

History.document;      // creates a document with current history

History.showLogFolder; // opens the folder where logs are written.

History.showLogFile;   // opens the current log file as it was written.

​

​

// make a gui window, to access code history lines at will,

// e.g. for code reuse in performance, adaptation, sharing, etc:

g = History.makeWin;

// specify left-bottom position, and number of lines in textview

g = History.makeWin(0@20, 5);

​

// play back the recorded history line by line

History.play(0);

​

​

// history can even record and play back stops with CmdPeriod.

// run these lines one at a time:

History.clear.start;

1 + 2;

2 + 3;

s.boot;

(dur: inf).play;

​

CmdPeriod.run; // or hit the Stop key command, Cmd-., or ctrl-.

3 + 4; // continue recording into history

4 + 5;

History.end;

​

// Replays history, including a CmdPeriod, and keeps replaying history.

History.play;

// same as first example:

History.clear.end;      // clear to start over

History.start;          // starts recording, opens log file

​

// execute these lines one by one

1 + 2;

p = ProxySpace.push(s.boot);

~a = {Dust.ar([1,1] * 30 ) * 0.3 };

~a.play;

~a.end;

​

History.end; // History.end ends logging as well.

​

​

History.document; // create a document with all the changes

History.showLogFile; // open the log file as it was written.

​

g = History.makeWin(0@20); // make a gui window, put it where you like

g = History.makeWin(0@20, 5); // number of lines in textview

​

History.play;                  // posts lines by default

History.play(verbose: false);  // just do it, no posting

​

// continue recording

History.start;

​

// enter 5 more lines

10 + 200;

p.push;

~b = { |freq=500| LFDNoise3.ar(freq.dup(2)) * 0.2 };

~b.play;

~b.set(\freq, 1000);

~b.end(2);

​

History.end;

​

// save current history to a file.

History.saveCS("~/Desktop/TestHist.scd");

h = History.new.loadCS("~/Desktop/TestHist.scd");

h.lines.printcsAll; "";

​

// Many History methods are redirected to History.current:

​

// History.current is where new codelines always go.

h = History.current;

h.lines.printcsAll; "";

​

// lineshorts are for gui display:

h.lineShorts.printcsAll; "";

​

// make a simple entry by hand.

History.enter("2 + 2");

h.lines.printcsAll; "";

​

// one can edit a history:

History.drop(-1); // drop the oldest memory

History.drop(1); // drop the newest memory

​

h.keep(9); h.lines.printAll; "";

h.drop(3); h.lines.printAll; "";

h.removeLast;       h.lines.printAll;"";

h.removeAt([3, 4]); h.lines.printAll;"";

​

// more examples

History.clear.start;

​

1 + 2; // code lines get stored

​

(nil + 2).postln; // error lines are ignored

​

// comment-only line is kept, empty lines not:

History.enter("// comment only");

History.enter(" ");

​

​

// save and load as text files

​

History.saveCS; // save as compilestring for reloading.

​

// save with name, in forward time order.

History.saveCS("~/Desktop/testHist.scd", forward: true);

​

// load back in from file

h = History.new.loadCS("~/Desktop/testHist.scd", forward: true);

h.lines.postcs; "";

​

// save as human-readable/hand-playable story

// write all to time-stamped file in historical order:

History.saveStory;

​

// ... with given filename.

History.saveStory("~/Desktop/myTestStory.scd");

​

// load from story format file

History.loadStory("~/Desktop/myTestStory.scd");

​

Document.open("~/Desktop/myTestStory.scd");    // the story file is human-readable.

​

​

// Various Internals

// make a new instance of History by hand:

h = History([

    [0, \me, "1+2"],

    [1.234, \me, "q = q ? ();"],

    [3, \me, "\"History\".postln"]]);

h.lines.printcsAll; "";

h.lineShorts.printcsAll; "";

​

h.play; // play it back

h.stop;

​

​

// string formatting utils

h.storyString;

History.formatTime(1234.56);

History.unformatTime("0:20:34.56");

​

(

History.prettyString("

​

/* removes line returns at start and end of code strings ... */

​

").postcs;

)

​

// convert a line to a short string of n characters for gui display

History.shorten(h.lines.first.postcs, 60).postcs;

​

​

// in networked setups, one may turn off local recording and rely on remote recording:

History.recordLocally

History.localOff

History.recordLocally

History.localOn

History.recordLocally

​

​

// by default, history always logs here (and makes the folder if not there yet):

History.logFolder;

History.showLogFolder;

History.logPath;

History.showLogFile; // current logfile...

// todo: optionally, one should be able to turn logging off?

​

// filtering lines, to get subsets of all lines by key and/or searchstring:

​

// get indices for specific keys

h = History([[0, \me, "a=1+2"], [1, \me, "3+5"], [1.234, \you, "q = q ? ();"], [3, \they, "\"The-story ==== \".postln"]]);

h.keys;

h.matchKeys(\me);

h.matchKeys(\you);

h.matchKeys(\they);

h.matchKeys;        // nil if no test

h.matchKeys(\all);  // all keys match

h.matchKeys([\me, \they])

h.matchKeys(\isidor) // empty array if no line found for this key

​

h.matchString("The-s");

h.matchString("q");

h.matchString("1+");

h.matchString("the-Story", false); // ignoreCase is false by default

h.matchString("the-Story", true); // ignoreCase

​

h.indicesFor([\me, \they], "=");    // indices for line written by \me or \her AND containing "=";

​

// searching is only an interface/access feature,

// so please read on at HistoryGui help ...

h.makeWin;

​

HistoryGui.help;