MenuAction | SuperCollider 3.13.0 Help

Location: NOT INSTALLED!

Description

A MenuAction represents a single action that can occupy multiple Menus or a ToolBars, and will evaluate a function when activated. When added to a menu, these are displayed as menu items. When added to a toolbar, they appear as buttons.

Class Methods

.new

Create a new Action. Note that one action may occupy multiple menus and toolbars.

Arguments:

string	The name of the action. This will be its display name if added to a menu.
function	A function to perform when the action is activated.

.separator

An action that represents a menu or toolbar separator. These are not selectable or clickable.

Arguments:

string

A label for the separator. These are not always visible, depending on your OS and context.

Inherited class methods

Instance Methods

.string

A string representing the name of the action. This is used as text when it is placed in menus, and on toolbars if it does not have an icon.

Arguments:

A String

.menu

A Menu. If present, this action acts as a submenu, or a pop-up menu when placed on a toolbar.

Arguments:

A Menu

.shortcut

A string representing the keyboard shortcut to trigger this action. Keyboard shortcuts are available when an action is attached to a ToolBar, or when it's part of the context menu for a View (see View: -setContextMenuActions) Shortcut strings are of the form e.g. "Ctrl+M", "Shift+Alt+space" etc. See https://doc.qt.io/qt-5/qkeysequence.html#details for more info.

Arguments:

A String

.checked

Indicates whether the action is checked or unchecked.

Arguments:

A boolean.

.toolTip

A string to display when hovering over the menu item / button.

Arguments:

A String

.separator

Indicates whether the action is a separator.

Arguments:

A Boolean.

.iconVisible

Indicates whether the icon for this action will be visible.

Arguments:

A Boolean.

.checkable

Indicates that the action shows a checkbox and is checkable.

Arguments:

A Boolean

.enabled

Indicates that the action is enabled; otherwise it will be greyed out and uninteractive.

Arguments:

A Boolean

.icon

An Image associated with the action - to be shown next to the name of the action in both menus and toolbars.

Arguments:

An Image

.font

The font used to display the action's name. Note that special fonts may or may not be displayed depending on OS and context (e.g. system menu, context menu, toolbar). For example, OSX application menus will honor italicized fonts, but not the font family itself.

Arguments:

A Font

Events

Menu actions broadcast several kinds of events that can be registered for with the standard Object: -addDependant calls. Events broadcast by menu:

\changed (issued when one of the actions properties changes)
\triggered (issued when the action is clicked / activated - value is a boolean representing whether the action is checked)
\hovered
\toggled

Events example( m = Menu( a = MenuAction("Option A"), b = MenuAction("Option B") ).title_("Event Example"); f = { |action, what, value| "MenuAction '%' sent event %, value = %".format(action.string, "\\" ++ what, value).postln; if (what == \hovered) { "Hovering over: %".format(action).postln }; if (what == \triggered) { "Action triggered: %".format(value).postln; m.destroy }; }; a.addDependant(f); b.addDependant(f); m.onClose_({ a.removeDependant(f); b.removeDependant(f) }).front; )

Inherited instance methods

Examples

Simple checkable menu item( ~view = View().layout_(HLayout( Button() .states_([["Options..."]]) .action_({ ~menu.front }) )); ~menu = Menu( MenuAction("enabled") .checkable_(true) .action_({ |a, enabled| if (enabled) { "Enabled".postln; ~view.background = Color.green(1, 0.5); } { "Disabled".postln; ~view.background = Color.clear; } }) ); ~view.front; )

Action help strings( ~view = View(bounds:300@100).layout_(VLayout( Button() .states_([["Options..."]]) .action_({ ~menu.front }), ~text = TextView() )); ~menu = Menu ( MenuAction("Option A").toolTip_("I like option A..."), MenuAction("Option B").toolTip_("But option B is better..."), MenuAction("Option C").toolTip_("No one really likes C."), ); ~actionFunc = { |obj, what, action| if (what == \hovered) { ~text.string = action.toolTip }; if (what == \aboutToHide) { ~text.string = "" } }; ~menu.addDependant(~actionFunc); ~view.onClose_({ ~menu.removeDependant(~actionFunc) }).front; )

A more complex example( s.waitForBoot { ~startIcon = Image(40).draw({ Pen.fillColor = Color.green; Pen.moveTo(5@5); Pen.lineTo(35@20); Pen.lineTo(5@35); Pen.lineTo(5@5); Pen.fill; }); ~stopIcon = Image(40).draw({ Pen.fillColor = Color.red; Pen.fillRect(Rect(10, 10, 20, 20)); }); ~startAction = MenuAction("start") .action_({ ~playSynth.() }) .icon_(~startIcon) .toolTip_("Start playing synth.") .shortcut_("space") .font_(Font(bold:true, size:18)); ~stopAction = MenuAction("stop") .action_({ ~stopSynth.() }) .icon_(~stopIcon) .toolTip_("Stop the synth.") .enabled_(false) .shortcut_(".") .font_(Font(bold:true, size:18)); ~playing = MenuAction("playing") .enabled_(false) .checkable_(true) .checked_(false); ~view = View(bounds:300@200).layout_(VLayout( ToolBar(~startAction, ~stopAction, MenuAction.separator, ~playing).focus, nil, Button().states_([["Options..."]]).action_({ Menu(~startAction, ~stopAction, MenuAction.separator, ~playing).front; }) )); ~view.onClose_({ ~stopSynth.() }); ~synth = nil; ~playSynth = { if (~synth.isNil) { ~synth = { SinOsc.ar(440) * 0.1 }.play; ~startAction.enabled = false; ~stopAction.enabled = true; ~playing.checked = true; ~synth.onFree({ ~synth = nil; { ~playing.checked = false; ~startAction.enabled = true; ~stopAction.enabled = false; }.defer }) } }; ~stopSynth = { ~synth !? { ~synth.free }; }; ~view.front; } )

helpfile source: https://github.com/supercollider/supercollider/tree/3.13/HelpSource/Classes/MenuAction.schelp
link::Classes/MenuAction::