Pgpar | SuperCollider 3.14.0 Help

Subclasses: Pgtpar

Description

Embeds several event streams so that they form a single output stream with all their events in temporal order. When one stream ends, the other streams are further embedded until all have ended.

NOTE: In order to fully separate these layers from other synths, use Pbus.

See Pgroup for a description of the \groupReleaseTime event key.

Class Methods

Pgpar.new(list, repeats: 1)

From superclass: ListPattern

Arguments:

list	list of patterns or streams.
repeats	repeat the whole pattern n times.

Examples

// an example analogous to the one in the Pfx helpfile

(

SynthDef(\echo, { |out = 0, maxdtime = 0.2, dtime = 0.2, decay = 2, gate = 1|
    var env, in;
    env = Linen.kr(gate, 0.05, 1, 0.1, 2);
    in = In.ar(out, 2);
    XOut.ar(out, env, CombL.ar(in * env, maxdtime, dtime, decay, 1, in));
}, [\ir, \ir, 0.1, 0.1, 0]).add;

SynthDef(\distort, { |out = 0, pregain = 40, amp = 0.2, gate = 1|
    var env;
    env = Linen.kr(gate, 0.05, 1, 0.1, 2);
    XOut.ar(out, env, (In.ar(out, 2) * pregain).distort * amp);
}, [\ir, 0.1, 0.1, 0]).add;

SynthDef(\wah, { |out = 0, gate = 1, rate = 0.3|
    var env, in;
    env = Linen.kr(gate, 0.05, 1, 0.4, 2);
    in = In.ar(out, 2);
    XOut.ar(out, env, RLPF.ar(in, LinExp.kr(LFNoise1.kr(rate), -1, 1, 200, 8000), 0.1).softclip * 0.8);
}, [\ir, 0]).add;
)

// watch the node structure as it changes
s.waitForBoot({ s.plotTree });

(
var p, q, r, o;
Pbus(
    Pgpar([
        Pbind(\degree, Prand((0..7), inf), \dur, 0.3, \legato, 0.2),
        Pbind(\instrument, \echo, \dur, 3, \legato, 1.1,
            \dtime, Pwhite(0.01, 0.1, inf), \decay, 3),
        Pbind(\instrument, \distort, \dur, 1.2, \legato, 1.1,
            \pregain, Pwhite(1, 20, inf), \amp, 0.25),
        Pbind(\instrument, \wah, \dur, 4.0, \legato, 1.1,
            \rate, Pwhite(0.1, 3, inf))
    ])
).play
)

helpfile source: https://github.com/supercollider/supercollider/tree/main/HelpSource/Classes/Pgpar.schelp
link::Classes/Pgpar::

Pgpar : Ppar : ListPattern : Pattern : AbstractFunction : Object

Description

Class Methods

Pgpar.new(list, repeats: 1)

Arguments:

Inherited class methods

Undocumented class methods

Pgpar.implClass

Instance Methods

Inherited instance methods

Undocumented instance methods

.embedInStream(inevent)

.numberOfGroups

.wrapPatterns(ids)

Examples