VOsc | SuperCollider 3.13.0 Help

Description

A wavetable lookup oscillator which can be swept smoothly across wavetables. Fractional values of table will interpolate between two adjacent tables.

This oscillator requires at least two buffers to be filled with a wavetable format signal. This preprocesses the signal into a form which can be used efficiently by the oscillator. All the wavetables must be allocated to the same size, and the size must be a power of two.

Setting your tables with Buffers

The wavetable can be generated by filling a buffer via the Buffer: Buffer Fill Commands (e.g. Buffer: -sine1). Set wavetable: true to ensure the proper data formatting.

Identically, you can create a Buffer object by sending one of the \b_gen messages \sine1, \sine2, \sine3 (see Server Command Reference: Wave Fill Commands and examples below), again remembering to enable the wavetable format.

You can use Buffer: *allocConsecutive to ensure a contiguous buffers numbers to be interpolated.

Setting your tables with Signals

This can also be achieved by creating a Signal object and sending it the Signal: -asWavetable message, saving it to disk, and having the server load it from there.

Class Methods

VOsc.ar(bufpos, freq: 440.0, phase: 0.0, mul: 1.0, add: 0.0)

VOsc.kr(bufpos, freq: 440.0, phase: 0.0, mul: 1.0, add: 0.0)

Arguments:

bufpos	Buffer index. Can be swept continuously among adjacent wavetable buffers of the same size.
freq	Frequency in Hertz. (non-interpolated control-rate)
phase	Phase offset or modulator in radians.
mul	Output will be multiplied by this value.
add	This value will be added to the output.

Inherited class methods

Instance Methods

Inherited instance methods

Examples

// allocate and fill the buffers to be used by VOsc
(
s.waitForBoot({

var numBufs = 8;

// allocate table of consecutive buffers
    ~bufs = Buffer.allocConsecutive(numBufs, s, 1024, 1);
    s.sync;

~bufs.do({ arg buf, i;
        var n, a;

// generate array of harmonic amplitudes
        n = (i+1)**2;
        a = Array.fill(n, { arg j; ((n-j)/n).squared.round(0.001) });

// fill table
        // argument '7': flag for the \sine1 wave fill method
        // see "Wave Fill Commands" in the Server Command Reference
        s.performList(\sendMsg, \b_gen, buf.bufnum, \sine1, 7, a);

s.sync;
    });
    "Buffers prepared.".postln;
})
)

// play the synth, indexing into the buffers with MouseX
(
x = SynthDef("help-VOsc",{ arg out = 0, bufoffset = 0;
    // mouse x controls the wavetable position
    var bufindex = MouseX.kr(0, ~bufs.size - 1) + bufoffset;

Out.ar(out,
        VOsc.ar(bufindex, [120, 121], 0, 0.3)
    )
}).play(s,[\out, 0, \bufoffset, ~bufs.first.bufnum]);
)

// fill the buffers with new harmonics on-the-fly
(
~bufs.do({ arg buf, i;
    var a;
    a = Array.fill(i, 0) ++ [0.5, 1, 0.5];
    s.performList(\sendMsg, \b_gen, buf.bufnum, \sine1, 7, a);
});
)

// new harmonics...
(
~bufs.do({ arg buf, i;
    var a = Array.fill(32,0);
    12.do({ arg i; a.put(32.rand, 1) });
    s.performList(\sendMsg, \b_gen, buf.bufnum, \sine1, 7, a);
});
)

// new harmonics...
(
~bufs.do({ arg buf, i;
    var a = Array.fill((i+1)**2, { arg j; 1.0.rand2 });
    s.performList(\sendMsg, \b_gen, buf.bufnum, \sine1, 7, a);
});
)

// cleanup
(
x.free;
~bufs.do(_.free);
)

helpfile source: https://github.com/supercollider/supercollider/tree/3.13/HelpSource/Classes/VOsc.schelp
link::Classes/VOsc::

VOsc : PureUGen : UGen : AbstractFunction : Object

VOsc.ar(bufpos, freq: 440.0, phase: 0.0, mul: 1.0, add: 0.0)

VOsc.kr(bufpos, freq: 440.0, phase: 0.0, mul: 1.0, add: 0.0)

Arguments: